How to use an arduino flow rate sensor to measure liquid flowing through a pipe/container

#### How to use an arduino flow rate sensor to measure liquid flowing through a pipe/container ## OVERVIEW

This tutorial teaches you how to use an arduino flow rate sensor to measure liquid flowing through a pipe/container in order to create a control system based on the water flow rate or quantity. For example this tutorial will help you how to measure the amount of water used to water your plants, so as to prevent wastage, etc.

Components Needed

1. Arduino Board
2. Liquid Flow meter.
3. Jumper wires.
4. Arduino Software IDE

So how does this work?
The arduino flow meter mentioned in the above link works on the principle of “Hall Effect”. According to which, a voltage difference is induced in a conductor transverse to the electric current and the magnetic field perpendicular to it. Here, Hall Effect is utilized in the flow meter using a small fan/propeller shaped rotor which is placed in the path of the liquid flowing.

The liquid thus pushes against the fins of the rotor, causing it to rotate. The shaft of the rotor is connected to a hall effect sensor. It is an arrangement of a current flowing coil and a magnet connected to the shaft of the rotor. Thus a voltage/pulse is induced as this rotor rotates. In this flow meter, for every litre of liquid passing through it per minute it outputs about 4.5 pulses.This is due to the changing magnetic field caused by the magnet attached to the rotor shaft, as seen in the picture below. We measure the number of pulses using an arduino. And then calculate the flow rate in L/hr using a simple conversion formula explained in step 2. Working of a flow rate sensor

#### Step 1 : Connecting the arduino flow rate sensor

Here, the connections required for this flow rate sensor with respect to arduino is very minimal. There are only three wires coming from the flow rate sensor. The 5V Vcc (Red wire) , The Gnd (Black wire) , and the signal/pulse (Usually yellow) line. Connect the Vcc and Gnd of the flow meter to the arduino’s Vcc and Gnd. The pulse line of the flow rate sensor is connected to arduino’s digital pin 2. The arduino’s digital pin 2 serves as an external interrupt pin (interrupt pin 0). Now you have hooked up your flow meter to the arduino. Arduino flow rate sensor connections

#### Step 2 : Upload the flow meter code to the arduino and measure water flow rate

Upload the code below to your arduino. Here the code uses an external interrupt on arduino’s digital pin 2. This is used to read the pulses coming from the flow meter. When arduino detects the pulse, it immediately triggers the pulseCounter() function . This function then counts the total number of pulses.

```/*
Liquid flow rate sensor -DIYhacking.com Arvind Sanjeev

Measure the liquid/water flow rate using this code.
Connect Vcc and Gnd of sensor to arduino, and the
signal line to arduino digital pin 2.

*/

byte statusLed    = 13;

byte sensorInterrupt = 0;  // 0 = digital pin 2
byte sensorPin       = 2;

// The hall-effect flow sensor outputs approximately 4.5 pulses per second per
// litre/minute of flow.
float calibrationFactor = 4.5;

volatile byte pulseCount;

float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;

unsigned long oldTime;

void setup()
{

// Initialize a serial connection for reporting values to the host
Serial.begin(38400);

// Set up the status LED line as an output
pinMode(statusLed, OUTPUT);
digitalWrite(statusLed, HIGH);  // We have an active-low LED attached

pinMode(sensorPin, INPUT);
digitalWrite(sensorPin, HIGH);

pulseCount        = 0;
flowRate          = 0.0;
flowMilliLitres   = 0;
totalMilliLitres  = 0;
oldTime           = 0;

// The Hall-effect sensor is connected to pin 2 which uses interrupt 0.
// Configured to trigger on a FALLING state change (transition from HIGH
// state to LOW state)
attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}

/**
* Main program loop
*/
void loop()
{

if((millis() - oldTime) > 1000)    // Only process counters once per second
{
// Disable the interrupt while calculating flow rate and sending the value to
// the host
detachInterrupt(sensorInterrupt);

// Because this loop may not complete in exactly 1 second intervals we calculate
// the number of milliseconds that have passed since the last execution and use
// that to scale the output. We also apply the calibrationFactor to scale the output
// based on the number of pulses per second per units of measure (litres/minute in
// this case) coming from the sensor.
flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;

// Note the time this processing pass was executed. Note that because we've
// disabled interrupts the millis() function won't actually be incrementing right
// at this point, but it will still return the value it was set to just before
// interrupts went away.
oldTime = millis();

// Divide the flow rate in litres/minute by 60 to determine how many litres have
// passed through the sensor in this 1 second interval, then multiply by 1000 to
// convert to millilitres.
flowMilliLitres = (flowRate / 60) * 1000;

// Add the millilitres passed in this second to the cumulative total
totalMilliLitres += flowMilliLitres;

unsigned int frac;

// Print the flow rate for this second in litres / minute
Serial.print("Flow rate: ");
Serial.print(int(flowRate));  // Print the integer part of the variable
Serial.print(".");             // Print the decimal point
// Determine the fractional part. The 10 multiplier gives us 1 decimal place.
frac = (flowRate - int(flowRate)) * 10;
Serial.print(frac, DEC) ;      // Print the fractional part of the variable
Serial.print("L/min");
// Print the number of litres flowed in this second
Serial.print("  Current Liquid Flowing: ");             // Output separator
Serial.print(flowMilliLitres);
Serial.print("mL/Sec");

// Print the cumulative total of litres flowed since starting
Serial.print("  Output Liquid Quantity: ");             // Output separator
Serial.print(totalMilliLitres);
Serial.println("mL");

// Reset the pulse counter so we can start incrementing again
pulseCount = 0;

// Enable the interrupt again now that we've finished sending output
attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}
}

/*
Insterrupt Service Routine
*/
void pulseCounter()
{
// Increment the pulse counter
pulseCount++;
}
```

In this arduino flow rate sensor, for every litre of liquid passing through it per minute it outputs about 4.5 pulses. Thus dividing the total pulse count obtained by 4.5 will give you the total amount of liquid passing through it in litres/minute. Further dividing it by 60 will give you the flow rate in litres/hr. And hence the total amount or quantity of water/liquid that has passed through it. The sensor  is accurate to within 3%.

Use this arduino flow rate sensor with a solenoid valve to monitor and control the water used. You can use it in your gardening system. Or interface it with an LCD display for other applications that require you to measure water flow rate and quantity. Have fun with your arduino flow rate sensor! Arduino flow rate sensor 